forked from tribes/guix
Taiju HIGASHI
5d22261db3
* guix/import/gem.scm: (rubygems-fetch, gem->guix-package) (gem-recursive-import): Fix to fetch the specified version of the gem. * guix/scripts/import/gem.scm (show-help): Update the help message. (guix-import-gem): Modify so the version number to be passed to subsequent procedures. * tests/gem.scm: Add tests. * doc/guix.texi (Invoking guix import): Document. Signed-off-by: Christopher Baines <mail@cbaines.net>
113 lines
4.0 KiB
Scheme
113 lines
4.0 KiB
Scheme
;;; GNU Guix --- Functional package management for GNU
|
|
;;; Copyright © 2015 David Thompson <davet@gnu.org>
|
|
;;; Copyright © 2018 Oleg Pykhalov <go.wigust@gmail.com>
|
|
;;; Copyright © 2021 Sarah Morgensen <iskarian@mgsn.dev>
|
|
;;; Copyright © 2021 Brice Waegeneire <brice@waegenei.re>
|
|
;;; Copyright © 2021 Simon Tournier <zimon.toutoune@gmail.com>
|
|
;;; Copyright © 2022 Taiju HIGASHI <higashi@taiju.info>
|
|
;;;
|
|
;;; This file is part of GNU Guix.
|
|
;;;
|
|
;;; GNU Guix is free software; you can redistribute it and/or modify it
|
|
;;; under the terms of the GNU General Public License as published by
|
|
;;; the Free Software Foundation; either version 3 of the License, or (at
|
|
;;; your option) any later version.
|
|
;;;
|
|
;;; GNU Guix is distributed in the hope that it will be useful, but
|
|
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;;; GNU General Public License for more details.
|
|
;;;
|
|
;;; You should have received a copy of the GNU General Public License
|
|
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
|
|
|
|
(define-module (guix scripts import gem)
|
|
#:use-module (guix ui)
|
|
#:use-module (guix utils)
|
|
#:use-module (guix scripts)
|
|
#:use-module (guix import gem)
|
|
#:use-module (guix scripts import)
|
|
#:use-module (srfi srfi-1)
|
|
#:use-module (srfi srfi-11)
|
|
#:use-module (srfi srfi-37)
|
|
#:use-module (ice-9 match)
|
|
#:use-module (ice-9 format)
|
|
#:use-module (ice-9 receive)
|
|
#:export (guix-import-gem))
|
|
|
|
|
|
;;;
|
|
;;; Command-line options.
|
|
;;;
|
|
|
|
(define %default-options
|
|
'())
|
|
|
|
(define (show-help)
|
|
(display (G_ "Usage: guix import gem PACKAGE-NAME[@VERSION] Import and
|
|
convert the RubyGems package for PACKAGE-NAME. Optionally, a version can be
|
|
specified after the at-sign (@) character.\n"))
|
|
(display (G_ "
|
|
-h, --help display this help and exit"))
|
|
(display (G_ "
|
|
-V, --version display version information and exit"))
|
|
(display (G_ "
|
|
-r, --recursive generate package expressions for all Gem packages\
|
|
that are not yet in Guix"))
|
|
(newline)
|
|
(show-bug-report-information))
|
|
|
|
(define %options
|
|
;; Specification of the command-line options.
|
|
(cons* (option '(#\h "help") #f #f
|
|
(lambda args
|
|
(show-help)
|
|
(exit 0)))
|
|
(option '(#\V "version") #f #f
|
|
(lambda args
|
|
(show-version-and-exit "guix import gem")))
|
|
(option '(#\r "recursive") #f #f
|
|
(lambda (opt name arg result)
|
|
(alist-cons 'recursive #t result)))
|
|
%standard-import-options))
|
|
|
|
|
|
;;;
|
|
;;; Entry point.
|
|
;;;
|
|
|
|
(define (guix-import-gem . args)
|
|
(define (parse-options)
|
|
;; Return the alist of option values.
|
|
(parse-command-line args %options (list %default-options)
|
|
#:build-options? #f))
|
|
|
|
(let* ((opts (parse-options))
|
|
(args (filter-map (match-lambda
|
|
(('argument . value)
|
|
value)
|
|
(_ #f))
|
|
(reverse opts))))
|
|
(match args
|
|
((spec)
|
|
(receive (package-name package-version)
|
|
(package-name->name+version spec)
|
|
(let ((code (if (assoc-ref opts 'recursive)
|
|
(map (match-lambda
|
|
((and ('package ('name name) . rest) pkg)
|
|
`(define-public ,(string->symbol name)
|
|
,pkg))
|
|
(_ #f))
|
|
(gem-recursive-import package-name package-version))
|
|
(let ((sexp (gem->guix-package package-name #:version package-version)))
|
|
(if sexp sexp #f)))))
|
|
(match code
|
|
((or #f '(#f))
|
|
(leave (G_ "failed to download meta-data for package '~a'~%")
|
|
package-name))
|
|
(_ code)))))
|
|
(()
|
|
(leave (G_ "too few arguments~%")))
|
|
((many ...)
|
|
(leave (G_ "too many arguments~%"))))))
|