forked from tribes/guix
Nicolas Graves
1f7ff47b7a
After this commit, when both modules are imported: - if pyproject is imported before, the warning is 'pypi-uri' is deprecated, use '(@ (guix build-system pyproject) pypi-uri)' instead - if python is imported before, the warning is `pypi-uri' imported from both (guix build-system python) and (guix build-system pyproject) This seems convenient enough to warn for deprecation in the short term, while avoiding any breaking changes. * guix/build-system/pyproject.scm (pypi-uri): Move the procedure from (guix build-system python) here. * guix/build-system/python (pypi-uri): Drop definition, import it from (guix build-system pyproject) and deprecate it. * gnu/packages/openldap.scm: Reorder modules to get the right warning. * gnu/packages/pypy.scm: Likewise. * gnu/packages/*.scm : Drop module (guix build-system python). * tests/import/pypi.scm: Likewise. Merges: https://codeberg.org/guix/guix/pulls/7448 Change-Id: Ib42f53bc545052eb7918a25afe9db6d5fc2cb834 Reviewed-by: Nguyễn Gia Phong <cnx@loang.net> Signed-off-by: Sharlatan Hellseher <sharlatanus@gmail.com>
262 lines
11 KiB
Scheme
262 lines
11 KiB
Scheme
;;; GNU Guix --- Functional package management for GNU
|
||
;;; Copyright © 2021 Lars-Dominik Braun <lars@6xq.net>
|
||
;;; Copyright © 2022 Marius Bakke <marius@gnu.org>
|
||
;;;
|
||
;;; This file is part of GNU Guix.
|
||
;;;
|
||
;;; GNU Guix is free software; you can redistribute it and/or modify it
|
||
;;; under the terms of the GNU General Public License as published by
|
||
;;; the Free Software Foundation; either version 3 of the License, or (at
|
||
;;; your option) any later version.
|
||
;;;
|
||
;;; GNU Guix is distributed in the hope that it will be useful, but
|
||
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
|
||
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
||
;;; GNU General Public License for more details.
|
||
;;;
|
||
;;; You should have received a copy of the GNU General Public License
|
||
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
|
||
|
||
(define-module (guix build-system pyproject)
|
||
#:use-module ((gnu packages) #:select (search-auxiliary-file))
|
||
#:use-module (guix gexp)
|
||
#:use-module (guix store)
|
||
#:use-module (guix utils)
|
||
#:use-module (guix gexp)
|
||
#:use-module ((guix licenses) #:prefix license:)
|
||
#:use-module (guix monads)
|
||
#:use-module (guix packages)
|
||
#:use-module (guix search-paths)
|
||
#:use-module (guix build-system)
|
||
#:use-module (guix build-system gnu)
|
||
#:use-module (guix build-system trivial)
|
||
#:use-module (srfi srfi-1)
|
||
#:use-module (ice-9 match)
|
||
#:export (%pyproject-build-system-modules
|
||
default-pytest-guix-plugin
|
||
default-python
|
||
default-sanity-check.py
|
||
pypi-uri
|
||
pyproject-build
|
||
pyproject-build-system
|
||
pyproject-guile-json))
|
||
|
||
;; Commentary:
|
||
;;
|
||
;; Standard build procedure for Python packages using 'pyproject.toml'.
|
||
;; This is implemented as an extension of 'python-build-system'.
|
||
;;
|
||
;; Code:
|
||
|
||
(define* (pypi-uri name version #:optional (extension ".tar.gz"))
|
||
"Return a URI string for the Python package hosted on the Python Package
|
||
Index (PyPI) corresponding to NAME and VERSION. EXTENSION is the file name
|
||
extension, such as '.tar.gz'."
|
||
(string-append "https://files.pythonhosted.org/packages/source/"
|
||
(string-take name 1) "/" name "/"
|
||
name "-" version extension))
|
||
|
||
(define %pyproject-build-system-modules
|
||
;; Build-side modules imported by default.
|
||
`((guix build pyproject-build-system)
|
||
(guix build toml)
|
||
,@%default-gnu-imported-modules))
|
||
|
||
(define (default-python)
|
||
"Return the default Python package, resolved lazily."
|
||
;; We are using python-sans-pip-wrapper, because it does not contain
|
||
;; setuptools. This allows us to skip the dependency on setuptools for
|
||
;; packages which don’t need it. And it allows us to more easily swap
|
||
;; out setuptools if a different version is required.
|
||
(@* (gnu packages python) python-sans-pip-wrapper))
|
||
|
||
(define (pyproject-guile-json)
|
||
"Return the default guile-json package, resolved lazily."
|
||
(@* (gnu packages guile) guile-json-4))
|
||
|
||
;; Maybe try to upstream it at some point, it's currently flavored for guix
|
||
;; but the idea itself is more general.
|
||
(define (default-pytest-guix-plugin python)
|
||
(let* ((effective (version-major+minor (package-version python)))
|
||
(site (string-append "lib/python" effective "/site-packages/")))
|
||
(package
|
||
(name "python-pytest-guix")
|
||
(version "0.0.1")
|
||
(source (local-file (search-auxiliary-file "python/pytest_guix.py")))
|
||
(build-system trivial-build-system)
|
||
(arguments
|
||
(list
|
||
#:modules '((guix build utils))
|
||
#:builder
|
||
#~(begin
|
||
(use-modules (guix build utils))
|
||
(let* ((site (string-append #$output "/" #$site))
|
||
(dist (string-append site "pytest_guix-" #$version
|
||
".dist.info")))
|
||
(mkdir-p dist)
|
||
(copy-file #$source (string-append site "/pytest_guix.py"))
|
||
(call-with-output-file (string-append dist "/entry_points.txt")
|
||
(lambda (port)
|
||
(format port "[pytest11]~%guix=pytest_guix~%")))))))
|
||
(home-page "https://guix.gnu.org/")
|
||
(synopsis "Ignore selected pytest options")
|
||
(description
|
||
"This package provides the script to cleanly ignore pytest options at the
|
||
build-system level.")
|
||
(license license:gpl3+))))
|
||
|
||
(define %default-pytest-guix-options
|
||
;; Guile keyword arguments are translated to Python keyword arguments
|
||
;; and passed to `group.addoption'. pytest_guix assumes default options
|
||
;; '(#:action "append" #:nargs "?")
|
||
;; It is required to store at least the store_const and store_true actions
|
||
;; to ensure boolean args are not eating the next argument, but it is not
|
||
;; necessary to do more than that so keep it minimal for maintainability.
|
||
#~'(("cov"
|
||
("--cov")
|
||
("--cov-reset" #:action "store_const")
|
||
("--cov-report")
|
||
("--cov-config")
|
||
("--no-cov-on-fail" #:action "store_true")
|
||
("--no-cov" #:action "store_true")
|
||
("--cov-fail-under")
|
||
("--cov-append" #:action "store_true")
|
||
("--cov-branch" #:action "store_true")
|
||
("--cov-precision")
|
||
("--cov-context"))
|
||
("html"
|
||
("--html")
|
||
("--self-contained-html" #:action "store_true")
|
||
("--css"))
|
||
("mypy"
|
||
("--mypy" #:action "store_true")
|
||
("--mypy-ignore-missing-imports" #:action "store_true")
|
||
("--mypy-config-file")
|
||
("--mypy-report-style")
|
||
("--mypy-no-status-check" #:action "store_true")
|
||
("--mypy-xfail" #:action "store_true"))
|
||
("isort" ("--isort" #:action "store_true"))
|
||
("flake8" ("--flake8" #:action "store_true"))
|
||
("black" ("--black" #:action "store_true"))
|
||
("flakes" ("--flakes" #:action "store_true"))
|
||
("pep8" ("--pep8" #:action "store_true"))))
|
||
|
||
;; TODO: On the next iteration of python-team, migrate the sanity-check to
|
||
;; importlib_metadata instead of setuptools.
|
||
(define (default-sanity-check.py)
|
||
(local-file (search-auxiliary-file "python/sanity-check.py")))
|
||
|
||
(define* (lower name
|
||
#:key source inputs native-inputs outputs system target
|
||
test-backend
|
||
(python (default-python))
|
||
(python-pytest-guix (default-pytest-guix-plugin python))
|
||
(sanity-check.py (default-sanity-check.py))
|
||
#:allow-other-keys
|
||
#:rest arguments)
|
||
"Return a bag for NAME."
|
||
(define private-keywords
|
||
'(#:target #:python #:inputs #:native-inputs
|
||
#:python-pytest-guix #:sanity-check.py))
|
||
(define native-inputs-labels (map car native-inputs))
|
||
(define has-pytest?
|
||
(or (member "python-pytest-bootstrap" native-inputs-labels)
|
||
(member "python-pytest" native-inputs-labels)))
|
||
|
||
|
||
(and (not target) ;XXX: no cross-compilation
|
||
(bag
|
||
(name name)
|
||
(system system)
|
||
(host-inputs `(,@(if source
|
||
`(("source" ,source))
|
||
'())
|
||
,@inputs
|
||
|
||
;; Keep the standard inputs of 'gnu-build-system'.
|
||
,@(standard-packages)))
|
||
(build-inputs
|
||
`(("python" ,python)
|
||
("sanity-check.py" ,sanity-check.py)
|
||
,@(if (and has-pytest?
|
||
(match test-backend
|
||
((or 'pytest-with-guix-plugin #f) #t)
|
||
(_ #f)))
|
||
`(("python-pytest-guix" ,python-pytest-guix))
|
||
`())
|
||
,@native-inputs))
|
||
(outputs (append outputs '(wheel)))
|
||
(build pyproject-build)
|
||
(arguments (strip-keyword-arguments private-keywords arguments)))))
|
||
|
||
(define* (pyproject-build name inputs
|
||
#:key source
|
||
(tests? #t)
|
||
(configure-flags ''())
|
||
(backend-path #f)
|
||
(build-backend #f)
|
||
(test-backend #f)
|
||
(test-flags ''())
|
||
(pytest-guix-options %default-pytest-guix-options)
|
||
(phases '%standard-phases)
|
||
(outputs '("out" "wheel"))
|
||
(search-paths '())
|
||
(system (%current-system))
|
||
(guile #f)
|
||
(guile-json (pyproject-guile-json))
|
||
(imported-modules %pyproject-build-system-modules)
|
||
(modules '((guix build pyproject-build-system)
|
||
(guix build utils)))
|
||
allowed-references
|
||
disallowed-references)
|
||
"Build SOURCE using PYTHON, and with INPUTS."
|
||
(define build
|
||
(with-extensions (list guile-json)
|
||
(with-imported-modules imported-modules
|
||
#~(begin
|
||
(use-modules #$@(sexp->gexp modules))
|
||
|
||
#$(with-build-variables inputs outputs
|
||
#~(pyproject-build
|
||
#:name #$name
|
||
#:source #+source
|
||
#:configure-flags #$configure-flags
|
||
#:system #$system
|
||
#:backend-path #$backend-path
|
||
#:build-backend #$build-backend
|
||
#:test-backend #$test-backend
|
||
#:test-flags #$test-flags
|
||
#:tests? #$tests?
|
||
#$@(let ((labels (map car inputs)))
|
||
(if (or (member "python-pytest-bootstrap" labels)
|
||
(member "python-pytest" labels))
|
||
#~(#:pytest-guix-options #$pytest-guix-options)
|
||
#~()))
|
||
#:phases #$(if (pair? phases)
|
||
(sexp->gexp phases)
|
||
phases)
|
||
#:outputs %outputs
|
||
#:search-paths '#$(sexp->gexp
|
||
(map search-path-specification->sexp
|
||
search-paths))
|
||
#:inputs %build-inputs))))))
|
||
|
||
|
||
(mlet %store-monad ((guile (package->derivation (or guile (default-guile))
|
||
system #:graft? #f)))
|
||
(gexp->derivation name build
|
||
#:system system
|
||
#:graft? #f ;consistent with 'gnu-build'
|
||
#:target #f
|
||
#:guile-for-build guile
|
||
#:allowed-references allowed-references
|
||
#:disallowed-references disallowed-references)))
|
||
|
||
(define pyproject-build-system
|
||
(build-system
|
||
(name 'pyproject)
|
||
(description "The PEP517-compliant Python build system")
|
||
(lower lower)))
|
||
|
||
;;; pyproject.scm ends here
|