;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2017 David Craven <david@craven.ch>
;;; Copyright © 2017, 2019 Mathieu Othacehe <m.othacehe@gmail.com>
;;; Copyright © 2020 Julien Lepiller <julien@lepiller.eu>
;;; Copyright © 2020 Jan (janneke) Nieuwenhuizen <janneke@gnu.org>
;;; Copyright © 2022 Maxim Cournoyer <maxim@guixotic.coop>
;;; Copyright © 2023 Efraim Flashner <efraim@flashner.co.il>
;;; Copyright © 2023-2024 Herman Rimm <herman@rimm.ee>
;;; Copyright © 2024 Zheng Junjie <873216071@qq.com>
;;; Copyright © 2025 dan <i@dan.games>
;;; Copyright © 2026 Artyom V. Poptsov <poptsov.artyom@gmail.com>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu bootloader u-boot)
  #:use-module (gnu bootloader extlinux)
  #:use-module (gnu bootloader)
  #:use-module (gnu packages bootloaders)
  #:use-module (guix gexp)
  #:use-module (ice-9 match)
  #:export (u-boot-bootloader
            u-boot-a20-olinuxino-lime-bootloader
            u-boot-a20-olinuxino-lime2-bootloader
            u-boot-a20-olinuxino-micro-bootloader
            u-boot-bananapi-m2-ultra-bootloader
            u-boot-am335x-evm-bootloader
            u-boot-beaglebone-black-bootloader
            u-boot-cubietruck-bootloader
            u-boot-firefly-rk3399-bootloader
            u-boot-mx6cuboxi-bootloader
            u-boot-novena-bootloader
            u-boot-orangepi-r1-plus-lts-rk3328-bootloader
            u-boot-orangepi-zero2w-bootloader
            u-boot-pine64-plus-bootloader
            u-boot-pine64-lts-bootloader
            u-boot-pinebook-bootloader
            u-boot-pinebook-pro-rk3399-bootloader
            u-boot-nanopi-r4s-rk3399-bootloader
            u-boot-puma-rk3399-bootloader
            u-boot-rock-4c-plus-rk3399-bootloader
            u-boot-rock64-rk3328-bootloader
            u-boot-rockpro64-rk3399-bootloader
            u-boot-sifive-unmatched-bootloader
            u-boot-qemu-riscv64-bootloader
            u-boot-starfive-visionfive2-bootloader
            u-boot-ts7970-q-2g-1000mhz-c-bootloader
            u-boot-wandboard-bootloader))

(define (make-u-boot-installer file)
  (let ((file
          (match file
            ((? string?)
             (list #~(install-file (string-append bootloader #$file)
                                   install-dir)))
            ((? file-like?)
             (list #~(mkdir-p install-dir)
                   #~(copy-file #$file
                                (string-append install-dir
                                               "/"
                                               #$(plain-file-name file)))))
            (#f '()))))
    #~(lambda (bootloader device mount-point)
        (let ((install-dir (string-append mount-point "/boot")))
          #$@file))))

(define (write-u-boot-image files block-size)
  "FILES is a list of (FILE COUNT OFFSET) tuples.  Each FILE is written
to the target image at BLOCK-SIZE * OFFSET.  The number of bytes written
is BLOCK-SIZE * COUNT, or FILE size if COUNT is not given."
  (define (write-file-to-image file)
    (match file
      ((file count ... offset)
       (let* ((file #~(string-append bootloader "/libexec/" #$file))
              (size (match count
                      (() #~(stat:size (stat #$file)))
                      ((count) (* count block-size)))))
         #~(write-file-on-device #$file #$size image
                                 #$(* offset block-size))))))
  #~(lambda (bootloader _ image)
      #$@(map write-file-to-image files)))

(define install-u-boot
  #~(lambda (bootloader root-index image)
      (if bootloader
        (error "Failed to install U-Boot"))))

(define install-am335x-evm-u-boot
  (write-u-boot-image
   ;; According to the "26.1.8.5.5 MMC/SD Read Sector Procedure in Raw Mode"
   ;; section in the "AM335x and AMIC110 Sitara™ Processors Technical
   ;; Reference Manual", we have offset, the bootrom tries to load code at the
   ;; offsets 0x0, 0x20000 (128KB), 0x40000 (256KB) and 0x60000 (384KB).
   ;;
   ;; The MBR is 512 Bytes
   ;; (https://en.wikipedia.org/wiki/Master_boot_record#Sector_layout).
   ;;
   ;; At the time of writing, u-boot.img is 1.4 MiB, and it is at offset
   ;; 0x60000 (384KB) as per CONFIG_SYS_MMCSD_RAW_MODE_U_BOOT_SECTOR.
   ;;
   ;; We also need to align the first partition to make sure read/writes are
   ;; properly aligned.
   ;;
   ;; Given these constraints, we chose the following partitioning:
   ;;
   ;; 0   512 Bytes    128 KiB
   ;; |       |        (0x20000)   256 KiB
   ;; |       |           /        (0x40000)       384 KiB            4 MiB
   ;; |       |          /            |            (0x60000)           |
   ;; |       |         /             |               |                |
   ;; v       v        /              v               v                v
   ;; +-------+        +--------------+---------------+----------------+
   ;; |  MBR  |   ...  |  First MLO   |  Second MLO   |   u-boot.img   |
   ;; +-------+        +--------------+---------------+----------------+
   ;; <-512 B->   ...  <-- 128 KiB --> <-- 128 KiB --> <-- 3712 KiB -->
   ;;
   ;; The rationale for that is as follows:
   ;;
   ;; - We add a second copy of the MLO at 256 KiB for improving reliability
   ;;   as the doc/board/ti/am335x_evm.rst documentation in u-boot advise us
   ;;   to do that, and also because the space there isn't used.
   ;;
   ;; - All can fit into 2MiB (u-boot.img can grow up to 1664 KiB), but we
   ;;   want a bit more space in case u-boot.img grows over time, so we allow
   ;;   u-boot to grow until the 4 MiB offset.
   '(("MLO" 256 256) ;; First MLO
     ("MLO" 256 512) ;; Second MLO
     ("u-boot.img" 7424 768)) 512))

(define install-beaglebone-black-u-boot
  ;; http://wiki.beyondlogic.org/index.php?title=BeagleBoneBlack_Upgrading_uBoot
  ;; This first stage bootloader called MLO (U-Boot SPL) is expected at
  ;; 0x20000 by BBB ROM code. The second stage bootloader will be loaded by
  ;; the MLO and is expected at 0x60000.  Write both first stage ("MLO") and
  ;; second stage ("u-boot.img") images, read in BOOTLOADER directory, to the
  ;; specified DEVICE.
  (write-u-boot-image '(("MLO" 256 256) ("u-boot.img" 768 1024)) 512))

(define install-allwinner-u-boot
  (write-u-boot-image '(("u-boot-sunxi-with-spl.bin" 8)) 1024))

(define install-allwinner64-u-boot
  (write-u-boot-image '(("u-boot-sunxi-with-spl.bin" 8)
                        ("u-boot-sunxi-with-spl.fit.itb" 40))
                      1024))

(define install-imx-u-boot
  (write-u-boot-image '(("SPL" 1) ("u-boot.img" 69)) 1024))

(define install-puma-rk3399-u-boot
  (write-u-boot-image '(("idbloader.img" 64) ("u-boot.itb" 512)) 512))

(define install-rockchip-u-boot
  (write-u-boot-image '(("idbloader.img" 64) ("u-boot.itb" 16384)) 512))

(define install-sifive-unmatched-u-boot
  (write-u-boot-image '(("spl/u-boot-spl.bin" 34) ("u-boot.itb" 2082))
                      512))

(define install-starfive-visionfive2-u-boot
  (write-u-boot-image '(("spl/u-boot-spl.bin.normal.out" 34)
                        ("u-boot.itb" 2082))
                      512))

(define install-starfive-visionfive2-uEnv.txt
  (make-u-boot-installer
    ;; If the board SPI uses the vendor's U-Boot, it will find starfive/
    ;; starfive_visionfive2.dtb.  We cannot guarantee that users will
    ;; update this U-Boot, so set the FDT explicitly.
    (plain-file "uEnv.txt"
                (string-join
                 (list
                  "boot_targets=mmc1 nvme0 mmc0 dhcp"
                  "bootcmd_mmc1=bootflow scan"
                  "fdtfile=starfive/jh7110-starfive-visionfive-2-v1.3b.dtb")
                 "\n"))))


;;;
;;; Bootloader definitions.
;;;

(define u-boot-bootloader
  (bootloader
   (inherit extlinux-bootloader)
   (name 'u-boot)
   (package #f)
   (installer #f)
   (disk-image-installer install-u-boot)))

(define u-boot-am335x-evm-bootloader
  (bootloader
   (inherit u-boot-bootloader)
   ;; This bootloader supports the following computers:
   ;; - SanCloud BeagleBone Enhanced
   ;; - SanCloud BeagleBone Enhanced Extended WiFi
   ;; - SanCloud BeagleBone Enhanced Lite
   ;; - Seeed Studio BeagleBone Green Eco
   ;; - TI AM3359 ICE-V2
   ;; - TI AM335x BeagleBone
   ;; - TI AM335x BeagleBone Black
   ;; - TI AM335x BeagleBone Green
   ;; - TI AM335x EVM
   ;; - TI AM335x EVM-SK
   ;; - TI AM335x PocketBeagle
   ;;
   ;; This list was made by retrieving the list of Devicetrees used in
   ;; configs/am335x_evm_defconfig in u-boot source code. Once we have that we
   ;; can look at each Devicetree in arch/arm/boot/dts/ti/omap/ inside Linux,
   ;; and in each file, look at the model property to find the name of the
   ;; computers that this image supports.
   (package u-boot-am335x-evm)
   ;; At the time of writing, our u-boot.img is 1.4 MiB. This is why we can't
   ;; reuse install-beaglebone-black-u-boot. And having the same image being
   ;; able to boot on multiple computers is useful.
   (disk-image-installer install-am335x-evm-u-boot)))

(define u-boot-beaglebone-black-bootloader
  (bootloader
   (inherit u-boot-bootloader)
   (package u-boot-am335x-boneblack)
   (disk-image-installer install-beaglebone-black-u-boot)))

(define u-boot-allwinner-bootloader
  (bootloader
   (inherit u-boot-bootloader)
   (disk-image-installer install-allwinner-u-boot)))

(define u-boot-allwinner64-bootloader
  (bootloader
   (inherit u-boot-bootloader)
   (disk-image-installer install-allwinner64-u-boot)))

(define u-boot-imx-bootloader
  (bootloader
   (inherit u-boot-bootloader)
   (disk-image-installer install-imx-u-boot)))

(define u-boot-rockchip-bootloader
  ;; SD and eMMC use the same format
  (bootloader
   (inherit u-boot-bootloader)
   (disk-image-installer install-rockchip-u-boot)))

(define u-boot-a20-olinuxino-lime-bootloader
  (bootloader
   (inherit u-boot-allwinner-bootloader)
   (package u-boot-a20-olinuxino-lime)))

(define u-boot-a20-olinuxino-lime2-bootloader
  (bootloader
   (inherit u-boot-allwinner-bootloader)
   (package u-boot-a20-olinuxino-lime2)))

(define u-boot-a20-olinuxino-micro-bootloader
  (bootloader
   (inherit u-boot-allwinner-bootloader)
   (package u-boot-a20-olinuxino-micro)))

(define u-boot-bananapi-m2-ultra-bootloader
  (bootloader
   (inherit u-boot-allwinner-bootloader)
   (package u-boot-bananapi-m2-ultra)))

(define u-boot-cubietruck-bootloader
  (bootloader
    (inherit u-boot-allwinner-bootloader)
    (package u-boot-cubietruck)))

(define u-boot-firefly-rk3399-bootloader
  (bootloader
   (inherit u-boot-rockchip-bootloader)
   (package u-boot-firefly-rk3399)))

(define u-boot-mx6cuboxi-bootloader
  (bootloader
   (inherit u-boot-imx-bootloader)
   (package u-boot-mx6cuboxi)))

(define u-boot-wandboard-bootloader
  (bootloader
   (inherit u-boot-imx-bootloader)
   (package u-boot-wandboard)))

(define u-boot-novena-bootloader
  (bootloader
   (inherit u-boot-imx-bootloader)
   (package u-boot-novena)))

(define u-boot-orangepi-r1-plus-lts-rk3328-bootloader
  (bootloader
   (inherit u-boot-rockchip-bootloader)
   (package u-boot-orangepi-r1-plus-lts-rk3328)))

(define u-boot-orangepi-zero2w-bootloader
  (bootloader
   (inherit u-boot-allwinner-bootloader)
   (package u-boot-orangepi-zero2w)))

(define u-boot-pine64-plus-bootloader
  (bootloader
   (inherit u-boot-allwinner64-bootloader)
   (package u-boot-pine64-plus)))

(define u-boot-pine64-lts-bootloader
  (bootloader
   (inherit u-boot-allwinner-bootloader)
   (package u-boot-pine64-lts)))

(define u-boot-pinebook-bootloader
  (bootloader
   (inherit u-boot-allwinner64-bootloader)
   (package u-boot-pinebook)))

(define u-boot-puma-rk3399-bootloader
  (bootloader
   (inherit u-boot-bootloader)
   (package u-boot-puma-rk3399)
   (disk-image-installer install-puma-rk3399-u-boot)))

(define u-boot-rock-4c-plus-rk3399-bootloader
  (bootloader
   (inherit u-boot-rockchip-bootloader)
   (package u-boot-rock-4c-plus-rk3399)))

(define u-boot-rock64-rk3328-bootloader
  (bootloader
   (inherit u-boot-rockchip-bootloader)
   (package u-boot-rock64-rk3328)))

(define u-boot-rockpro64-rk3399-bootloader
  (bootloader
   (inherit u-boot-rockchip-bootloader)
   (package u-boot-rockpro64-rk3399)))

(define u-boot-pinebook-pro-rk3399-bootloader
  (bootloader
   (inherit u-boot-rockchip-bootloader)
   (package u-boot-pinebook-pro-rk3399)))

(define u-boot-nanopi-r4s-rk3399-bootloader
  (bootloader
   (inherit u-boot-rockchip-bootloader)
   (package u-boot-nanopi-r4s-rk3399)))

(define u-boot-ts7970-q-2g-1000mhz-c-bootloader
  ;; This bootloader doesn't really need to be installed, as it is read from
  ;; an SPI memory chip, not the SD card.  It is copied to /boot/u-boot.imx
  ;; for convenience and should be manually flashed at the U-Boot prompt.
  (bootloader
   (inherit u-boot-bootloader)
   (package u-boot-ts7970-q-2g-1000mhz-c)
   (installer (make-u-boot-installer "libexec/u-boot.imx"))
   (disk-image-installer #f)))

(define u-boot-sifive-unmatched-bootloader
  (bootloader
   (inherit u-boot-bootloader)
   (package u-boot-sifive-unmatched)
   (disk-image-installer install-sifive-unmatched-u-boot)))

(define u-boot-starfive-visionfive2-bootloader
  (bootloader
   (inherit u-boot-bootloader)
   (package u-boot-starfive-visionfive2)
   (installer install-starfive-visionfive2-uEnv.txt)
   (disk-image-installer install-starfive-visionfive2-u-boot)))

(define u-boot-qemu-riscv64-bootloader
  (bootloader
   (inherit u-boot-bootloader)
   (package u-boot-qemu-riscv64)
   (installer (make-u-boot-installer "libexec/u-boot.bin"))
   (disk-image-installer #f)))