mirror of
https://git.savannah.gnu.org/git/guix.git
synced 2026-05-01 23:05:57 +02:00
Mathieu Lirzin
a9edb211e7
Before that '.log' files for scheme tests were fragmented and not included in test-suite.log. This unifies the semantics of SRFI-64 API with Automake test suite. * build-aux/test-driver.scm: New file. * Makefile.am (SCM_LOG_DRIVER, AM_SCM_LOG_DRIVER_FLAGS): New variables. (SCM_LOG_COMPILER, AM_SCM_LOG_FLAGS): Delete variables. (AM_TESTS_ENVIRONMENT): Set GUILE_AUTO_COMPILE to 0. * test-env.in: Silence guix-daemon. * doc/guix.texi (Running the Test Suite): Describe how to display the detailed results. Bug reports require only 'test-suite.log' file. * tests/base32.scm, tests/build-utils.scm, tests/builders.scm, tests/challenge.scm, tests/cpan.scm, tests/cpio.scm, tests/cran.scm, tests/cve.scm, tests/derivations.scm, tests/elpa.scm, tests/file-systems.scm, tests/gem.scm, tests/gexp.scm, tests/gnu-maintenance.scm, tests/grafts.scm, tests/graph.scm, tests/gremlin.scm, tests/hackage.scm, tests/hash.scm, tests/import-utils.scm, tests/lint.scm, tests/monads.scm, tests/nar.scm, tests/packages.scm, tests/pk-crypto.scm, tests/pki.scm, tests/profiles.scm, tests/publish.scm, tests/pypi.scm, tests/records.scm, tests/scripts-build.scm, tests/scripts.scm, tests/services.scm, tests/sets.scm, tests/size.scm, tests/snix.scm, tests/store.scm, tests/substitute.scm, tests/syscalls.scm, tests/system.scm, tests/ui.scm, tests/union.scm, tests/upstream.scm, tests/utils.scm: Don't exit at the end of test groups. * tests/containers.scm: Likewise. Use 'test-skip' instead of exiting with error code 77.
106 lines
4.2 KiB
Scheme
106 lines
4.2 KiB
Scheme
;;; GNU Guix --- Functional package management for GNU
|
|
;;; Copyright © 2016 Ludovic Courtès <ludo@gnu.org>
|
|
;;;
|
|
;;; This file is part of GNU Guix.
|
|
;;;
|
|
;;; GNU Guix is free software; you can redistribute it and/or modify it
|
|
;;; under the terms of the GNU General Public License as published by
|
|
;;; the Free Software Foundation; either version 3 of the License, or (at
|
|
;;; your option) any later version.
|
|
;;;
|
|
;;; GNU Guix is distributed in the hope that it will be useful, but
|
|
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;;; GNU General Public License for more details.
|
|
;;;
|
|
;;; You should have received a copy of the GNU General Public License
|
|
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
|
|
|
|
(define-module (test-scripts-build)
|
|
#:use-module (guix tests)
|
|
#:use-module (guix store)
|
|
#:use-module (guix packages)
|
|
#:use-module (guix scripts build)
|
|
#:use-module (guix ui)
|
|
#:use-module (guix utils)
|
|
#:use-module (gnu packages base)
|
|
#:use-module (gnu packages busybox)
|
|
#:use-module (ice-9 match)
|
|
#:use-module (srfi srfi-64))
|
|
|
|
|
|
(test-begin "scripts-build")
|
|
|
|
(test-assert "options->transformation, no transformations"
|
|
(let ((p (dummy-package "foo"))
|
|
(t (options->transformation '())))
|
|
(with-store store
|
|
(eq? (t store p) p))))
|
|
|
|
(test-assert "options->transformation, with-source"
|
|
;; Our pseudo-package is called 'guix.scm' so the 'guix.scm' source should
|
|
;; be applicable.
|
|
(let* ((p (dummy-package "guix.scm"))
|
|
(s (search-path %load-path "guix.scm"))
|
|
(t (options->transformation `((with-source . ,s)))))
|
|
(with-store store
|
|
(let ((new (t store p)))
|
|
(and (not (eq? new p))
|
|
(string=? (package-source new)
|
|
(add-to-store store "guix.scm" #t
|
|
"sha256" s)))))))
|
|
|
|
(test-assert "options->transformation, with-source, with version"
|
|
;; Our pseudo-package is called 'guix.scm' so the 'guix.scm-2.0' source
|
|
;; should be applicable, and its version should be extracted.
|
|
(let ((p (dummy-package "foo"))
|
|
(s (search-path %load-path "guix.scm")))
|
|
(call-with-temporary-directory
|
|
(lambda (directory)
|
|
(let* ((f (string-append directory "/foo-42.0.tar.gz"))
|
|
(t (options->transformation `((with-source . ,f)))))
|
|
(copy-file s f)
|
|
(with-store store
|
|
(let ((new (t store p)))
|
|
(and (not (eq? new p))
|
|
(string=? (package-name new) (package-name p))
|
|
(string=? (package-version new) "42.0")
|
|
(string=? (package-source new)
|
|
(add-to-store store (basename f) #t
|
|
"sha256" f))))))))))
|
|
|
|
(test-assert "options->transformation, with-source, no matches"
|
|
;; When a transformation in not applicable, a warning must be raised.
|
|
(let* ((p (dummy-package "foobar"))
|
|
(s (search-path %load-path "guix.scm"))
|
|
(t (options->transformation `((with-source . ,s)))))
|
|
(with-store store
|
|
(let* ((port (open-output-string))
|
|
(new (parameterize ((guix-warning-port port))
|
|
(t store p))))
|
|
(and (eq? new p)
|
|
(string-contains (get-output-string port)
|
|
"had no effect"))))))
|
|
|
|
(test-assert "options->transformation, with-input"
|
|
(let* ((p (dummy-package "guix.scm"
|
|
(inputs `(("foo" ,coreutils)
|
|
("bar" ,grep)
|
|
("baz" ,(dummy-package "chbouib"
|
|
(native-inputs `(("x" ,grep)))))))))
|
|
(t (options->transformation '((with-input . "coreutils=busybox")
|
|
(with-input . "grep=findutils")))))
|
|
(with-store store
|
|
(let ((new (t store p)))
|
|
(and (not (eq? new p))
|
|
(match (package-inputs new)
|
|
((("foo" dep1) ("bar" dep2) ("baz" dep3))
|
|
(and (eq? dep1 busybox)
|
|
(eq? dep2 findutils)
|
|
(string=? (package-name dep3) "chbouib")
|
|
(match (package-native-inputs dep3)
|
|
((("x" dep))
|
|
(eq? dep findutils)))))))))))
|
|
|
|
(test-end)
|